home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wildcat Files 2
/
The Wildcat Files 2 (Arsenal Computer).ISO
/
qm-util
/
qmail4.scr
< prev
next >
Wrap
Text File
|
1994-04-02
|
5KB
|
178 lines
;
; QuickLearn Script generated at 02:25:48 on 08-30-88
; May require editing before use.
;
; -----------------------------------------------------------------
;
TurnOn 8_BIT ; defaults from QuickLearn...
TurnOff LINEFEED
TurnOff XON/XOFF
TurnOff NOISE
TurnOff MUSIC
TurnOn SCROLL
TurnOff PRINT
TurnOff ECHO
; ;
; --------------------------- DEFINITIONS ------------------------- ;
; ;
String QWKFILE REPFILE QWKPATH REPPATH FONTXT
String NAME XFER UDONE DDONE DOOR
Assign QWKFILE EXECNET.QWK ; Name of QWK file
Assign REPFILE EXECNET.REP ; Name of REP file
Assign QWKPATH L:\QMAIL\ ; DRIVE:\PATH of QWK file
Assign REPPATH L:\QMAIL\ ; DRIVE:\PATH of REP file
Assign FONTXT Exec-Mail-Stop ; Unique text in FON file
Assign NAME "John Friel XXX" ; Your Name and Password on BBS
Assign DOOR "QMAIL" ; QMail Door # on BBS
Assign XFER G ; Protocol to transfer with
Assign UDONE N ; Upload done?
Assign DDONE N ; Download done?
; ------------------------- END DEFINITIONS -----------------------
Restart: ; Go here if the connection gets broken...
; The DIAL command uses the ability to call a specific
; number, without knowing the exact position in the
; .FON file. In my FON book, ExecNet has the unique text
; string stored in $FONTXT. So, by using the new Tag Text
; and specifying this, it will dial this number even
; if the FON book is sorted. Note the 'T' prefix...
If $ONLINE SkipD ; Skip the dial if already online
Dial "T$FONTXT" ;
; Note: This Script does NOT have to be linked to the
; entry in the FON book, but it makes it easier to
; edit if it is. Just press 'V' when the scrollbar is
; on the RFM QwikNet entry!
SkipD:
TimeOut 300 QQ ; Set Waitfor timeout to 300 seconds. {5 minutes}
Goto TOP ; Jump to the start of the main body.
QQ: ; Something timed out
If $OffLine Restart ; are we offline? If so, restart script
Send "^M"
If "$DDONE" = "N" DownSection ; Go do Download again
If "$UDONE" = "N" UpSection ; Go do Upload again
; If we get here, then both the upload and download were completed, but
; we didn't get offline correctly, so lets go do the endgame and quit
Goto EndGame
;----;
TOP: ; Main Body of the NetMail Script
;----;
; Set up all Question/Answer responses that might
; be generated by the QwikNet hub.
;-----------------------------------------------------------;
; ---- PROMPT ---- -- REPLY -- ;
;-----------------------------------------------------------;
When
When "Press (Enter) to continue?" "^M"
When "graphics (Enter)=no?" "Y Q^M"
When "What is your first name?" "$NAME^M"
When "Since 'Last Read' (Enter)=yes?" "N^M"
When "Check your Mail for messages" "N^M"
When "Conference members (Enter)=no?" "N^M"
When "More (Y), (N), (NS)" "N^M"
When "Enter Language #" "2^M"
When "(H)elp, More?" "N^M"
When "NO CARRIER" Restart ;(a Goto label)
Waitfor "Command?"
Delay 100
Send "OPEN $DOOR^M"
;-----------;
ReDownload:
;-----------;
Waitfor "<COMMAND>"
Delay 100
;------------;
DownSection:
;------------;
Send "D^M"
When
When "NO CARRIER" Restart
When "<NO TRANSFER>" DoRepsNow
Waitfor "<DLASK>"
Delay 100
Send "Y^M"
Waitfor "<DOWNLOAD>"
Delay 100
Send "^M"
Download $XFER $QWKPATH$QWKFILE
If $SUCCESS SuccessDown
Goto ReDownload
;------------;
SuccessDown:
;------------;
Assign DDONE Y ; Download was successful
Goto DoRepsNow
;----------;
UpSection:
;----------;
Send "^M"
Waitfor "<COMMAND>"
Delay 100
;----------;
DoRepsNow:
;----------;
When
When "NO CARRIER" Restart
Exist $REPPATH$REPFILE SendEm
Goto AllDone
;-------;
SendEm: ; there are replies to send!
;-------;
Delay 1000
Send "^M"
Waitfor "<COMMAND>"
Send "U^M"
Delay 100
Waitfor "<UPLOAD>"
Pause 1000
Upload $XFER $REPPATH$REPFILE
If $FAIL UpSection
Assign UDONE Y ; Upload of REP is OK
Dos "Del $REPPATH$REPFILE" ; now, delete the REP file...
;--------;
AllDone:
;--------;
Waitfor "<COMMAND>"
Pause 1000
Send "G^M"
Pause 2000
;--------;
EndGame:
;--------;
Hangup ; Hangup the modem
Delay 1000
Send "ATM0H1^M" ; Place the modem "off-hook"
System Y ; Exit back to the Batch file to insert new msgs.
Exit ; End of Script